[EO] Checkpoint Attribute

[Alatar]

I was bored and decided to make something like adding a new attribute to Origins. The Checkpoint Attribute is a simple addition to [EO] that sets the basic of a checkpoint tile and stores it in a .ini file, so when a player dies he/she respawns there. This can easily be optimized in order to increase the utility of it, because the code below is a scratch of what could it be.
No credits are needed ^^, hope you people find it useful ;D

**Design**:

- frmEditor_Map: Add a new option button below optSlide named “optCheckpoint”.

**Code**:

**Server-Side**:

- modConstants: Below this:
```
Public Const TILE_TYPE_SLIDE As Byte = 14
```Add this:
```
Public Const TILE_TYPE_CHECKPOINT As Byte = 15
```
- modDatabase: In AddChar, below:
```
Player(Index).Class = ClassNum
```Add:
```
Call PutVar(App.Path & "\Data\accounts\checkpoints.ini", "*SERVEROPTIONS*", "" & GetPlayerName(Index), "" & 0)
```
- modPlayer: In PlayerMove, below this:
```
' Check if it's a trap tile
        If .Type = TILE_TYPE_TRAP Then
            amount = .Data1
            SendActionMsg GetPlayerMap(Index), "-" & amount, BrightRed, ACTIONMSG_SCROLL, GetPlayerX(Index) * 32, GetPlayerY(Index) * 32, 1
            If GetPlayerVital(Index, HP) - amount <= 0 Then
                KillPlayer Index
                PlayerMsg Index, "You're killed by a trap.", BrightRed
            Else
                SetPlayerVital Index, HP, GetPlayerVital(Index, HP) - amount
                PlayerMsg Index, "You're injured by a trap.", BrightRed
                Call SendVital(Index, HP)
            End If
            Moved = YES
        End If
```
Add this before the End With:
```
        If .Type = TILE_TYPE_CHECKPOINT Then
            SetCheckpoint Index, .Data1, .Data2, .Data3
        End If
```
In the same module, in Sub OnDeath, find this:
```
    With Map(GetPlayerMap(Index))
      ' to the bootmap if it is set
        If .BootMap > 0 Then
            PlayerWarp Index, .BootMap, .BootX, .BootY
        Else
            Call PlayerWarp(Index, START_MAP, START_X, START_Y)
        End If
    End With
```Replace with this:
```
    With Map(GetPlayerMap(Index))
        'Checkpoint
        If ValCheckPoint(Index) = True Then
            WarpToCheckpoint Index
        ' to the bootmap if it is set
        ElseIf .BootMap > 0 Then
            PlayerWarp Index, .BootMap, .BootX, .BootY
        Else
            Call PlayerWarp(Index, START_MAP, START_X, START_Y)
        End If
    End With
```
And at the end of the module add this subs:

```
'Checkpoint
Public Sub SetCheckpoint(ByVal Index As Long, ByVal MapNum As Long, ByVal x As Long, ByVal y As Long)
    PlayerMsg Index, "Checkpoint activated!", BrightGreen
    Call PutVar(App.Path & "\Data\accounts\checkpoints.ini", "*SERVEROPTIONS*", "" & GetPlayerName(Index), "" & 1)
    Call PutVar(App.Path & "\Data\accounts\checkpoints.ini", "" & GetPlayerName(Index), "MAPNUM", "" & MapNum)
    Call PutVar(App.Path & "\Data\accounts\checkpoints.ini", "" & GetPlayerName(Index), "X", "" & x)
    Call PutVar(App.Path & "\Data\accounts\checkpoints.ini", "" & GetPlayerName(Index), "Y", "" & y)
End Sub

Public Sub WarpToCheckpoint(ByVal Index As Long)
    Dim MapNum As Integer
    Dim x As Integer
    Dim y As Integer

    MapNum = GetVar(App.Path & "\Data\accounts\checkpoints.ini", "" & GetPlayerName(Index), "MAPNUM")
    x = GetVar(App.Path & "\Data\accounts\checkpoints.ini", "" & GetPlayerName(Index), "X")
    y = GetVar(App.Path & "\Data\accounts\checkpoints.ini", "" & GetPlayerName(Index), "Y")
    Call PlayerWarp(Index, MapNum, x, y)
End Sub

Public Function ValCheckPoint(ByVal Index As Long) As Boolean
    If GetVar(App.Path & "\Data\accounts\checkpoints.ini", "*SERVEROPTIONS*", "" & GetPlayerName(Index)) = 1 Then
        ValCheckPoint = True
    Else
        ValCheckPoint = False
    End If
End Function
```

**Client-Side**:

- modConstants: Below this:
```
Public Const TILE_TYPE_SLIDE As Byte = 14
```Add this:
```
Public Const TILE_TYPE_CHECKPOINT As Byte = 15
```
- modGameEditors: Find this
```
' slide
If frmEditor_Map.optSlide.Value Then
.Type = TILE_TYPE_SLIDE
.Data1 = MapEditorSlideDir
.Data2 = 0
.Data3 = 0
End If
```
Below it, add this:
```
'Checkpoint
If frmEditor_Map.optCheckpoint.Value Then
If movedMouse Then Exit Sub
X = X - (CurX * 32)
Y = Y - (CurY * 32)
.Type = TILE_TYPE_CHECKPOINT
.Data1 = GetPlayerMap(MyIndex)
.Data2 = CurX
.Data3 = CurY
End If
```
- modText: Find this:
```
Case TILE_TYPE_SLIDE
DrawText TexthDC, tX, tY, "S", QBColor(BrightCyan)
```
Below, add this:

```
Case TILE_TYPE_CHECKPOINT
DrawText TexthDC, tX, tY, "CP", QBColor(BrightGreen)
```

[Sir Cid]

This is what I needed so badly, would give it more dimension. I'm gonna try it out…

EDIT: Works perfectly! Thanks so much, Alatar!

[Ertzel]

Nice code. I did this before with scripting but never tried it in EO with source editing. This will help me a lot :D

Thx for the tutorial.

[Icie Juicy]

Great code, I'll plug it in and play around with it.

[Helladen]

Bug here:
```
  If GetVar(App.Path & "\Data\accounts\checkpoints.ini", "*SERVEROPTIONS*", "" & GetPlayerName(Index)) = 1 Then
```
Needs to be changed to:
```
  If GetVar(App.Path & "\Data\accounts\checkpoints.ini", "*SERVEROPTIONS*", "" & GetPlayerName(Index)) = "1" Then
```
These "" tell that it's an integer and not a preset value that has been dimmed or a function. This is a very important fix, as it will cause regular players to crash the client/server.

[Alatar]

Thx to that! I haven't seen it xD

[Helladen]

It's in your tutorial…

[erkro1]

Does this work with eo xmas?
If not, would you please make a tutorial for it?

[westin444]

I highly suggest you add this directly to the player data, not an INI  :S

[Alatar]

Oh yea, the topic is from September, I think that storing in playerrec could be better and quicker.

[Skillzalot]

Nice little system you have here. I took your system and edited it to my needs and it works amazingly thank you.

[evilbunnie]

@Helladen:

> These "" tell that it's an integer and not a preset value that has been dimmed or a function.


[ohnoitsbenjii]

This works beautifully. Perhaps there is a way to make a button that would allow you to go to the checkpoints, like a "gate out" function? if anyone could figure that out, please do share? <3

[Ansonla]

can this be added in eo2?

[RaiKalGames]

yes

[Ansonla]

theres something wrong with this code. i don't know why. someone fix it. it's not working for me.

[Mondo]

Works Great! Thank you for sharing! :D

[quintensky]

@Ansonla:

> theres something wrong with this code. i don't know why. someone fix it. it's not working for me.

there is nothing wong with the code, you did it wrong…

about the tut:
Thanks alot, i needed this! map 1 and 2 are tutorial maps in my game :P and i don't want players to respawn inside the tutorial cave :S well, Thanks alot